Initの例 (GNU Emacs マニュアル)

次へ: ターミナル固有の初期化, 前へ: Initファイルの構文, 上へ: Emacs初期化ファイル [目次][索引]

51.4.2 初期化ファイルの例 ¶

一般的によく求められる処理をLisp式で実装した例をいくつか挙げます。

変数 load-path にディレクトリを追加します。これにより、Emacs に同梱されていない Lisp ライブラリをこのディレクトリに配置し、M-x load-library でロードできるようになります。Emacs 用 Lisp コードライブラリを参照してください。
```
(add-to-list 'load-path "/path/to/lisp/libraries")
```
Cモードの TAB では、ポイントが行の途中にある場合にタブを挿入するようにしてください。
```
(setq c-tab-always-indent nil)
```
ここでは、値が通常「true」のときはtとなり、それ以外の「false」のときはnilとなる変数があります。
デフォルトで検索を大文字小文字区別にする（これを上書きしていないすべてのバッファにおいて）。
```
(setq-default case-fold-search nil)
```
これによりデフォルト値が設定され、当該変数のローカル値を持たないすべてのバッファで有効になります（ローカル変数を参照）。case-fold-search を setq で設定すると、現在のバッファのローカル値にのみ影響が及びますが、これは初期化ファイルで意図する動作ではないと思われます。
Emacsが正しく判定できない場合は、独自のメールアドレスを指定してください。
```
(setq user-mail-address "cheney@torture.gov")
```
Messageモードなどの各種Emacsパッケージは、メールアドレスを知る必要がある際にuser-mail-addressを参照します。メールヘッダフィールドを参照してください。
新規バッファのデフォルトモードをテキストモードにする。
```
(setq-default major-mode 'text-mode)
```
なお、text-mode が使われているのは、これがテキストモードに入るためのコマンドだからです。直前のシングルクォートによってこの記号は定数となります。そうでなければ、text-mode は変数名として扱われてしまいます。
西欧のほとんどの言語をサポートするLatin-1文字セットのデフォルト設定を行う。
```
(set-language-environment "Latin-1")
```
グローバルマイナーモードである行番号モードをオフにする。
```
(line-number-mode 0)
```
テキストモードおよび関連モードで、オートフィルモードを自動的に有効にします（Hooksを参照）。
```
(add-hook 'text-mode-hook 'auto-fill-mode)
```
クリップボードを使用する際の符号化方式を変更します（プロセス間通信の符号化方式を参照）。
```
(setopt selection-coding-system 'utf-8)
```
foo という名前のインストール済み Lisp ライブラリ（実際には標準的な Emacs ディレクトリにある foo.elc または foo.el というファイル）をロードします。
```
(load "foo")
```
load の引数が相対ファイル名であり、‘/’ や ‘~’ で始まらない場合、load は load-path 内のディレクトリを検索します（Emacs用Lispコードライブラリを参照）。
ホームディレクトリからコンパイル済みのLispファイル foo.elc をロードしてください。
```
(load "~/foo.elc")
```
ここでは完全なファイル名が使用されているため、検索は行われません。
mypackage という名前の Lisp ライブラリ（すなわちファイル mypackage.elc または mypackage.el）を読み込んで、関数 myfunction の定義を Emacs に探させる：
```
(autoload 'myfunction "mypackage" "Do what I say." t)
```
ここでは、文字列 "Do what I say." が関数のドキュメント文字列となります。これを autoload の定義で指定することで、パッケージがロードされていない状態でもヘルプコマンドで参照できるようになります。最後の引数 t は、この関数がインタラクティブであることを示します。つまり、M-x myfunction RET と入力するか、キーにバインドすることで、対話的に呼び出すことができます。関数がインタラクティブでない場合は、t を省略するか、nil を使用してください。
キー C-x l を再バインドして、関数 make-symbolic-link を実行します（Init ファイルでのキーの再バインドを参照）。
```
(keymap-global-set "C-x l" 'make-symbolic-link)
```
または
```
(keymap-set global-map "C-x l" 'make-symbolic-link)
```
変数としての値ではなく、記号 make-symbolic-link を指すためにシングルクォートが用いられている点に、改めて注目してください。

Lispモードのみ同様の処理を行う。

(keymap-set lisp-mode-map "C-x l" 'make-symbolic-link)

ファンダメンタルモードで現在 next-line が実行されているすべてのキーを、代わりに forward-line が実行されるように再定義します。
```
(keymap-substitute global-map 'next-line 'forward-line)
```
C-x C-v を undefined にする。
```
(keymap-global-unset "C-x C-v")
```
キーを未定義にする理由の一つは、それをプレフィックスにできるようにするためです。単に C-x C-v anything を定義すれば C-x C-v はプレフィックスになりますが、C-x C-v については、まず通常の非プレフィックスとしての定義を解除する必要があります。
テキストモードにおいて、‘$’が句読点の構文を持つようにしてください。‘$’に文字定数を使用している点に注意してください。
```
(modify-syntax-entry ?\$ "." text-mode-syntax-table)
```
確認なしでコマンド narrow-to-region を使用できるようにする。
```
(put 'narrow-to-region 'disabled nil)
```
各種プラットフォームやEmacsのバージョンに合わせて設定を調整する。
通常、ユーザーはEmacsがすべてのシステムで同じように動作することを望みます。そのため、すべてのプラットフォームで同じinitファイルを使用するのが適切です。しかし、Emacsのカスタマイズに使用している関数が、一部のプラットフォームや古いバージョンのEmacsでは利用できないことがあります。このような状況に対処するには、次のように、その関数や機能が利用可能かどうかを判定する条件式の中にカスタマイズ内容を記述します。
```
(if (fboundp 'blink-cursor-mode)
    (blink-cursor-mode 0))

(if (boundp 'coding-category-utf-8)
    (set-coding-priority '(coding-category-utf-8)))
```
関数が定義されていない場合に発生するエラーは、単に無視しても構いません。
```
(ignore-errors (set-face-background 'region "grey75"))
```
存在しない変数に対する setq は一般的に無害であるため、それらに条件式は不要です。
use-package を使用してパッケージを自動的に読み込み、設定する。
```
(use-package hi-lock
  :defer t
  :init (add-hook 'some-hook 'hi-lock-mode)
  :config (use-package my-hi-lock)
  :bind (("M-o l" . highlight-lines-matching-regexp)
         ("M-o r" . highlight-regexp)
         ("M-o w" . highlight-phrase)))
```
これにより、一部のコマンドや変数が最初に使用された際に hi-lock がロードされ、3つのキーがそのコマンドにバインドされるほか、hi-lock のロード後に my-hi-lock パッケージ（おそらく hi-lock をさらにカスタマイズするもの）がロードされます。use-package の機能については専用のマニュアルに詳細が記載されています。use-package ユーザーマニュアルを参照してください。